Cara Melihat Product Key Windows 10 yang Sudah Terinstall

Cara Melihat Product Key Windows 10 yang Sudah Terinstall

Product key windows 10 juga seperti halnya versi windows sebelumnya yang biasanya terdapat pada CD/DVD asli dan juga biasanya terdapat pada komputer case yang terinstall windows 10 asli. Jika Kita tiba-tiba kehilangan kunci product (product key) windows 8, dan kepingin menemukan kembali product key windows 10 yang hilang tadi, Kita dapat menemukannya dengan mudah dengan bantuan sebuah software khusus maupun tanpa menginstall dan mendownload software pihak ke tiga (3).

Ada beberapa cara yang dapat sobat gunakan menggunakan software maupun tanpa menggunakan bantuan software.  Nah, Pembahasan saya kali ini yaitu mengenai cara melihat product key windows 10 yang sudah terinstall di komputer tanpa menggunakan software karena memang lebih praktis dan sobat tidak usah khawatir untuk penggunaannya sendiri juga cukup mudah. Di sini kita hanya menggunakan aplikasi bawaan windows, tidak hanya tersedia bagi windows 10 akan tetapi juga pada versi windows sebelumnya. Nama aplikasi yang saya maksud adalah notepad mungkin sobat juga tidak asing lagi dengan aplikasi yang satu ini. Meskipun aplikasi ini memiliki ukuran yang kecil dan juga sangat ringan saat dijalankan akan tetapi memiliki fungsi yang cukup penting salah satunya seperti yang saya bahas tadi.

Cara Melihat Product Key Windows 10 tanpa software

1.  Pertama-tama buka aplikasi notepad. Bagi yang belum tahu caranya tekan tombol windows + R secara bersamaan pada keyboard untuk membuka RUN. Setelah itu ketikan notepad dan tekan enter.
2. Masukkan atau ketikkan kode di bawah ini ke dalam notepad. Jika tidak bisa dicopas, silahkan copas saja kodenya yang berwarna kuning di artikel ini.   Option Explicit
   
   Dim objshell,path,DigitalID, Result
   Set objshell = CreateObject("WScript.Shell")
   'Set registry key path
   Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
   'Registry key value
   DigitalID = objshell.RegRead(Path & "DigitalProductId")
   Dim ProductName,ProductID,ProductKey,ProductData
   'Get ProductName, ProductID, ProductKey
   ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
   ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
   ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
   ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
   'Show messbox if save to a file
   If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
      Save ProductData
   End If
   
   'Convert binary to chars
   Function ConvertToKey(Key)
       Const KeyOffset = 52
       Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
       'Check if OS is Windows 8
       isWin8 = (Key(66) \ 6) And 1
       Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
       i = 24
       Maps = "BCDFGHJKMPQRTVWXY2346789"
       Do
           Current= 0
           j = 14
           Do
              Current = Current* 256
              Current = Key(j + KeyOffset) + Current
              Key(j + KeyOffset) = (Current \ 24)
              Current=Current Mod 24
               j = j -1
           Loop While j >= 0
           i = i -1
           KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
           Last = Current
       Loop While i >= 0
       keypart1 = Mid(KeyOutput, 2, Last)
       insert = "N"
       KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
       If Last = 0 Then KeyOutput = insert & KeyOutput
       ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
      
   End Function
   'Save data to a file
   Function Save(Data)
       Dim fso, fName, txt,objshell,UserName
       Set objshell = CreateObject("wscript.shell")
       'Get current user name
       UserName = objshell.ExpandEnvironmentStrings("%UserName%")
       'Create a text file on desktop
       fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
       Set fso = CreateObject("Scripting.FileSystemObject")
       Set txt = fso.CreateTextFile(fName)
       txt.Writeline Data
       txt.Close
   End Function
3. Simpan dengan nama WindowsKey.vbs atau terserah sobat mau memberi nama apa yang penting ada formatnya (.vbs) diakhir nama tadi.
4. Setelah itu buka file yang di simpan tadi, kemudian akan memunculkan informasi diantarannya, Product Name, Product ID, dan installed key (product key). 
5. Klik Yes jika pengen menyimpan filenya.

Tidak hanya dapat digunakan pada windows 10 saja, tetapi cara ini bisa sobat gunakan untuk melihat product key dari windows-windows sebelumnya seperti windows 7 maupun windows 8. Mungkin sampai di sini pembahasan mengenai Cara Melihat Product Key Windows 10. Jika ada kesulitan atau ada hal yang ingin disampaikan silahkan melalui komentar yang tersedia

Sumber : https://komputermesh.blogspot.co.id/2016/02/cara-melihat-product-key-windows-10.html 

jika bingung dan ingin memanggil jasa servis laptop bisa menghubungi tim kami

Inovasi Servis

Jl. Bendul Merisi 7/3. Surabaya

Telp/WA : 081333717417  (WA for fast respon)